Enzyme - Substrate

Author: Russ Harmer

We have two kinds of agents, an enzyme E and its substrate S, each with a single site, s, equipped with a binary state, 0 or 1, for inactive or active. The simplest possible binding rule allows the association of active enzyme with its substrate:

'r1'  E(s~1), S(s) -> E(s~1!0), S(s!0) @ k1

Let us also note the two natural refinements of this rule for the two possible states of the substrate:

'r10' E(s~1), S(s~0) -> E(s~1!0), S(s~0!0) @ k10
'r11' E(s~1), S(s~1) -> E(s~1!0), S(s~1!0) @ k11 # product inhibition

We also have corresponding unbinding rule r-1 and its refinements.

The second rule represents the modification of inactive substrate by a bound enzyme

'r2'  E(s~1!0), S(s~0!0) -> E(s~1), S(s~1) @ k2

which also undoes the binding between the enzyme and its modified substrate.

The attached kappa file contains all the rules; however, the only uncommented rules are r10, r-10, and r2. This is the default model.

Investigate the behaviour of this system, i.e. steady-state values of the two observables and the time to steady-state.

Vary the rate constants and/or numbers of S agents. Explain the consequences.

What changes if you replace rule r10 with r1? Why? Try other combinations of rules...

Download View code

%agent: E(s~1~0)
%agent: S(s~0~1)

%var: 'fast' 10
%var: 'medium' 1
%var: 'slow' 0.1
%var: 'BND' 0.00001
%var: 'BRK' 0.1
%var: 'MOD' 0.1

# enzyme-substrate binding
# 'r1'   E(s~1), S(s) -> E(s~1!0), S(s!0) @ 'BND'
'r10'  E(s~1), S(s~0) -> E(s~1!0), S(s~0!0) @ 'BND' # * 'fast'
# 'r11'  E(s~1), S(s~1) -> E(s~1!0), S(s~1!0) @ 'BND' # product inhibition

# unbinding
# 'r-1'  E(s!0), S(s!0) -> E(s), S(s) @ 'BRK'
'r-10' E(s!0), S(s~0!0) -> E(s), S(s~0) @ 'BRK'
# 'r-11' E(s!0), S(s~1!0) -> E(s), S(s~1) @ 'BRK'

# substrate activation
'r2'   E(s~1!1), S(s~0!1) -> E(s~1!1), S(s~1!1) @ 'MOD'

%init: 100 E(s~1)
%init: 1000 S(s~0)

%obs: 'active substrate' S(s~1?)