Growing ring and roaming agents

Author: Vincent Danos

This model grows a one dimensional ring and inserts new agents on it which diffuse along the ring; the idea is that this is a simple model of receptor clustering in a growing system. It is an interesting exercise to refine the diffusion rule to be compatible with a simple Ising potential modeling the binding of receptors (when they are next to each other on the ring). The improved, energy-modulated model is here.

The syntax is KaSim's.

Download View code

%agent: Mem(l, r, s)
%agent: Sensor(m)
%var: 'kInsert' 2E-6
%var: 'D' 0.018
%var: 'h' 3 # is this right?
%var: 'kMove' 'D'/('h'^2)
%var: 'kGrow' 8E-6
'Insert' Mem(s) -> Mem(s!1), Sensor(m!1) @ 'kInsert'
'Move1' Mem(s!1, l!2), Sensor(m!1), Mem(r!2, s) -> Mem(s, l!2), Sensor(m!1), Mem(r!2, s!1) @ 'kMove'
'Move2' Mem(s!1, r!2), Sensor(m!1), Mem(l!2, s) -> Mem(s, r!2), Sensor(m!1), Mem(l!2, s!1) @ 'kMove'
'Grow' Mem(l!1), Mem(r!1) -> Mem(l!1), Mem(r!2), Mem(r!1, l!2) @ 'kGrow'
%init: 1 (Mem(l!1, r!2), Mem(l!2, r!3), Mem(l!3, r!4), Mem(l!4, r!5), Mem(l!5, r!6), Mem(l!6, r!7), Mem(l!7, r!8), Mem(l!8, r!9), \
          Mem(l!9, r!10), Mem(l!10, r!1))
%obs: 'Mem' Mem()
%obs: 'Sensor' Sensor(m!_)
%plot: 'Sensor'/'Mem'