Independent binding (prozone effect) - RuleBase

Independent binding (prozone effect)

Author: Vincent Danos
tags: exercises

We consider a model where A, C can bind B independently (B could be a scaffold mediating between A and C). The parameters are relatively sticky resulting in 2/3 of As being bound given an equal number of As and Bs. Likewise for C. We want to study the equilibrium amount of ABC as a function of the total number of B's in the system.

The dependency is bell-shaped, and the curve can be obtained in one simulation by injecting Bs slowly enough so the system is always at equilibrium.

 

 

 

Download View code 
%agent: A(s)
%agent: B(s,t)
%agent: C(s)

%var: 'vol' 0.1
%var: 'nA'  1000 * 'vol'
#%var: 'nB'  1000 * 'vol'
%var: 'nB'  0 * 'vol'
%var: 'nC'  1000 * 'vol'

%init: 'nA' A(s)
%init: 'nB' B(s)
%init: 'nC' C(s)

%var: 'BND' 0.0005 / 'vol'
%var: 'BRK' 0.1
%var: 'MOD' 0.1

'assocAB'  A(s), B(s) -> A(s!0), B(s!0) @ 'BND'
'dissocAB' A(s!0), B(s!0) -> A(s), B(s) @ 'BRK'
'assocBC'  B(t), C(s) -> B(t!0), C(s!0) @ 'BND'
'dissocBC' B(t!0), C(s!0) -> B(t), C(s) @ 'BRK'

%obs: 'AB' B(s!_)
%obs: 'BC' B(t!_)
%obs: 'ABC' B(s!_,t!_)
%obs: 'B' B(s,t)
%obs: 'ABC fraction' 'ABC' / 'B'

%var: 'INJ' 0.1 * 'vol'
'inject' -> B(s,t) @ 'INJ'

%mod: [T] > 60000 do 'inject' := 0
about